Quelltext der Seite VMware:Scripte VMware Consolidated Backup

[[Kategorie:VMware]][[Kategorie:vSphere]][[Kategorie:Batch]]
==vcbMounter.exe==

Die vcbMounter.exe ist Bestandteil des "VMware Consolidated Backup" Paketes, welches eigentlich jeder der eine '''gekaufte''' ESX-Server besitzt, nutzen kann.<br>
Und ja - er funktioniert selbst unter vSphere 5 noch!<br>
Über den Aufruf von<br>

 vcbmounter.exe /?

oder bei jedem Aufruf mit einem falschen Parameter erscheint einer Hilfe.
Nachfolgend ein Beispielaufruf mit der Erklärung der Parameter:

 vcbmounter.exe -h SERVER -u BENUTZERNAME -p PASSWORT -a name:VMTest -m nbd -r d:\Backups\VMTest -t fullvm -M 1
  
                -h SERVER             : DNS-Name oder IP-Adresse des vCenter oder ESX-Servers
                -u BENUTZERNAME       : Anmeldename - Windows Benutzer bei vCenter, root bei ESX Servern. Ggf. mit Domäne\Benutzer angeben
                -p PASSWORT           : Das Passwort zum Benutzer
                -a name:VMTest        : Name der VM wie Sie in der Bestandsliste im vSphere/Infrasstrukture Client angezeigt wird, bei Leerzeichen " " verwenden.
                -m nbd                : Modus wie auf die VM zugegriffen wird: 
                                          nbd = über das TCP/IP Netzwerk
                                          san = direkt über einen HBA Adapter des Windows Rechners (muss lesend auf SAN-LUN's zugreifen können)
                -r d:\Backups\VMTest  : Sicherungspfad - den ersten Teil, hier "d:\Backups\" muss es schon geben, den Ordner "VMTest" legt er dann an.
                -t fullvm             : Was gesichert werden soll - ganze VM = Komplettkopie
                -M 1                  : 1 bedeutet, das er die VMDK-Festplatte als eine große Datei speichert, bei 0 oder weglassen des Parameters werden die
                                          Festplatten in 2GB Häppchen aufgeteilt.

vcbmounter.exe legt für die Sicherung vollautomatisch einen Snapshot der VM an - und löscht ihn, egal ob erfolgreich oder nicht, wieder bei, beenden.
Sie können den Aufruf con vcbmounter.exe mit STRG+C abbrechen - bitte warten Sie dann bis er fertig mit Aufräumen ist.

<u>'''Aber - wie spiele ich die gesicherte VM bei Bedarf wieder auf dem ESX Server ein?'''</u><br>
Die einfachste Methode ist über das VirtualCenter / vCenter mit Installieren VMware Converter.
Rufen Sie den Befehl "Maschine Importieren" auf und geben Sie als Quelle ein Backup / Datei an. Hier können Sie die VM auch gleich anpassen (Festplattengrößen etc.)


----
==Sichern von Virtuellen Maschinen per Batch-Datei==

Das VMware Consolidated Backup lässt sich auf beliebige Windows Rechner installieren (XP/7/2003/2008, 32 und 64Bit) und ermöglicht die einfache, komplette Sicherung einer kompletten VM. Die Daten der VM können dabei auf jeden beliebigen, vom Windows Rechner aus erreichbaren, Speicher abgelegt werden, z.B. lokale Festplatte oder USB-Festplatten.

Die nachfolgende Bachdatei wurde im Zuge eines VMware Projektes als "schnelle Lösung" entwickelt - Ziel war es, das der dortige Admin eventuelle Änderungen in Zukunft selbst vornehmen kann, ohne gleich tiefer in die Materie eingehen zu müssen. Ich meine, die Datei an sich ist selbsterklärend.<br>
Kleiner Hinweis noch: die vcbmounter.exe wird hier ohne Pfad aufgerufen -> weil der Pfad der datei mit in die globale PATH Variable aufgenommen wurde.

[[Media:Vcbmounter-backup-vm.cmd‎]]
 @echo off
 REM ######################################################
 REM # vcbMounter Steuerdatei für Batchgesteuerte Backups #
 REM # Die Variablen mit den Passenden Werten belegen     #
 REM #                                                    #
 REM # 2009 von Bernhard Linz / Bernhard.Linz@t-online.de #
 REM ######################################################
 
 REM _________________________________________________________________________________________________________
 
 REM # Windows Benutzer, ggf. Domäne\Benutzer oder root falls direkter Zugriff auf ESX-Server
 SET BENUTZERNAME=vcbBackup
 
 REM # Passwort des Benutzers
 SET PASSWORT=Passw0rt
 
 REM # DNS-Name, NetBIOS-Name oder IP-Adresse des VirtualCenter Servers, alternativ des ESX-Servers
 SET vCenterServer=142.0.0.67
 
 REM # Pfad, wohin die VM gesichert werden sollen, Angabe mit abschliessenden "\", UNC Pfade erlaubt
 SET Sicherungspfad=D:\VM\
 
 REM # Dateiname mit Pfad, wohin die Logdatei über die Sicherung geschrieben werden soll
 SET LogfileMitPfad=D:\VMware-Scripte\vcbmounter-log.txt
 
 REM # Backup-Mode - nbd=Über das Netzwerk, san=über HBA Controller direkt vom SAN
 SET BACKUPMODE=nbd
 
 REM _________________________________________________________________________________________________________
 echo %DATE% + %TIME% Start der Sicherung von VM's mit vcbmounter von Rechner %COMPUTERNAME% > %LogfileMitPfad%
 REM ##########################################################################
 REM Nachfolgend immer eine Zeile für die zu sicherne VM hinzufügen ###########
 REM Namen so wie er im vCenter dargestellt wird ##############################
 REM Bei Leerzeichen im Namen bitte in " " ####################################
 REM ##########################################################################
 
 call :backup Webserver
 call :backup SQL2008
 call :backup Mailserver
 
 goto ENDE
 
 REM _________________________________________________________________________________________________________
 REM ##########################################################################
 REM Subroutine backup ########################################################
 REM ##########################################################################
 
 :backup
 echo %DATE% + %TIME% Start %1 >> %LogfileMitPfad%
 rd /S /Q %Sicherungspfad%%1
 vcbmounter -h %vCenterServer% -u %BENUTZERNAME% -p %PASSWORT% -a name:%1 -m %BACKUPMODE% -r %Sicherungspfad%%1 -t fullvm -M 1
 echo %DATE% + %TIME% Ende %1 >> %LogfileMitPfad%
 goto :EOF
 
 REM _________________________________________________________________________________________________________
 :ENDE
 
----
<comments />