Quelltext der Seite Windows:Multi-Monitor Slideshow - Diashow über mehrere Monitore - mit IrfanView und einem Batch-Script

[[Katgorie:Sonstiges]][[Kategorie:Windows]][[Kategorie:Windows_XP]][[Kategorie:Windows_Server_2008]][[Kategorie:Windows_Vista]][[Kategorie:Windows_7]][[Kategorie:Batch]]
In einem Moment der Langeweile entstanden, alles andere als Perfekt (man sieht den Desktophintergund zwischendurch) - aber es funktioniert :-)<br>
<br>
Dieses Skript zeigt mit Hilfe von [http://www.irfanview.net/ IrfanView] eine Diashow / Slideshow eines Bilderordners an.<br>
Dabei verschiebt sich das Bild von
* Monitor 1 auf Monitor 2
* Monitor 2 auf Monitor 3
* Monitor 3 auf Monitor 4
* Monitor 4 auf Monitor 5
* Monitor 1 zeigt das nächste neue Bild
Es wird 5 Sekunden gewartet - und es geht von vorne los ...<br>
<br>
<u>'''Download: '''</u><big>[[Media:IrfanView_MulitMonitor_Slideshow_5_Monitors.cmd|IrfanView_MulitMonitor_Slideshow_5_Monitors.cmd]]</big>
<br>
<br>
<source lang="DOS">
@echo off
REM ##################################################################################################
REM Einfache Batchdatei die mit IrfanView eine Slideshow auf 2 oder mehr Monitoren gleichzeitig anzeigt.
REM Dabei wird auf Monitor 1 ein neues, auf Monitor 2 das Bild was auf Monitor 1 war angezeit
REM kann theoretisch beliebig erweitert werden.
REM Grundidee irgendwo mal im Web gefunden und an heutige Verhältnisse angepasst.
REM 2012 Bernhard Linz
REM Bernhard@znil.net
REM Bernhard.Linz@datagroup.de
REM veröffentlicht auf znilwiki: http://znil.net
REM
REM Bedienung: Ordner mit den Bilder einfach per Drag & Drop auf dieses Script ziehen.
REM oder Skript starten mit dem Bilderordner als Argument
REM zeigt nur *.JPG Bilder an. (Könnte aber angepasst werden)
REM
REM Azahl der Sekunden ziwschen den Bildwechseln:
SET PAUSEZEIT=5
REM nachfolgend für jeden Monitor eine Zeile
SET BILDMONITOR2=
REM SET BILDMONITOR3=
REM SET BILDMONITOR4=
REM SET BILDMONITOR5=
REM Ordnerpfad per Drag & Drop (oder per Aufruf in der Kommandozeile)
FOR %%i in (%1\*.jpg) do call :SLIDESHOW "%%i"
REM call :DISPLAY
GOTO ENDE


:SLIDESHOW
REM Nachfolgend sind bis 5 Monitore mit einer Auflösung von 1280x1024 nebeneinander
REM Ihr müsst die Koordinaten anpassen - und für nicht vorhandenen Monitore einfach deren START Zeilen
REM auskommentieren.
REM Monitor 1, Koordinaten oben links = 0,0
START "-" "C:\Program Files (x86)\IrfanView\i_view32.exe" %1 /pos=(0,0) /fs /bf
REM Monitor 2, Rechts daneben, Koordinaten obere linke Ecke = 1280,0 (=Rechts neben Monitor 1)
START "-" "C:\Program Files (x86)\IrfanView\i_view32.exe" %BILDMONITOR2% /pos=(1280,0) /fs /bf
REM Monitor 3, Rechts daneben, Koordinaten obere linke Ecke = 2560,0 (=Rechts neben Monitor 2)
START "-" "C:\Program Files (x86)\IrfanView\i_view32.exe" %BILDMONITOR3% /pos=(2560,0) /fs /bf
REM Monitor 4, Rechts daneben, Koordinaten obere linke Ecke = 3840,0 (=Rechts neben Monitor 3)
START "-" "C:\Program Files (x86)\IrfanView\i_view32.exe" %BILDMONITOR4% /pos=(3840,0) /fs /bf
REM Monitor 5, Rechts daneben, Koordinaten obere linke Ecke = 5120,0 (=Rechts neben Monitor 4)
START "-" "C:\Program Files (x86)\IrfanView\i_view32.exe" %BILDMONITOR5% /pos=(5120,0) /fs /bf

REM die Wartezeit warten (1 ping ist ca. 1 Sekunde)
PING 127.0.0.1 -n %PAUSEZEIT% > NUL 
REM Alle Irfan View Instanzen beenden:
"C:\Program Files (x86)\IrfanView\i_view32.exe" /killmesoftly
REM Bilder durchtauschen (alles 1 nach rechts verschieben)
SET BILDMONITOR5=%BILDMONITOR4%
SET BILDMONITOR4=%BILDMONITOR3%
SET BILDMONITOR3=%BILDMONITOR2%
SET BILDMONITOR2=%1
REM und Ende der Schleife, wird mit dem nächsten neuen Bild aufgerufen ....
GOTO :EOF

:ENDE
</source>